ESP32 Forum

Posted: **Sat Feb 03, 2024 12:20 am**

Hey everyone! I have an ESP32-S3 (attached to a Sunton display) and I want it to perform two tasks: displaying video that an ESP32-CAM transmits and blinking an LED (below is the main code):

Code: [Select all] [Expand/Collapse]

#include <Arduino.h>
 
#include "tasks.hpp"
 
TaskHandle_t video;
TaskHandle_t led;
 
void setup() {
    Serial.begin(115200);
    vTaskDelay(1000 / portTICK_PERIOD_MS);
 
    Serial.println();
    Serial.println("---SICABS Indoor---");
    Serial.println();
 
    xTaskCreatePinnedToCore(videoProjection, "Video projection", 200000, NULL, 1, &video, 1);
    xTaskCreatePinnedToCore(blinkLED, "blink LED", 200000, NULL, 1, &led, 0);
}
 
void loop() {
    vTaskDelete(NULL);
}

GeSHi © Codebox Plus Extension

The task for displaying video looks like this:

Code: [Select all] [Expand/Collapse]

void videoProjection(void* parameter) {
    gfx.init();
    gfx.setRotation(0);
    gfx.setColorDepth(16);
    gfx.setBrightness(127);
    gfx.fillScreen(TFT_BLACK);
    gfx.setSwapBytes(true);
 
    gfx.setFont(&fonts::lgfxJapanGothic_16);
    gfx.drawString("SICABS Indoor", 0, 0);
 
    // JPEG decoder
    TJpgDec.setJpgScale(1);
    TJpgDec.setCallback(tft_output);
 
    // WiFi
    WiFi.softAP(wifi_ssid, wifi_password);
    IPAddress IP = WiFi.softAPIP();
 
    // WebSockets
    server.listen(SERVER_PORT);
 
    Serial.print("Video task running on core ");
    Serial.println(xPortGetCoreID());
    for (;;) {
        if (server.poll()) {
            // if (!client.available()) {  // Always overwrite the client to the new one
            client = server.accept();
            client.onMessage(onMessageCallback);
            client.onEvent(onEventsCallback);
            client.send("Hello Client!");
            // }
        }
 
        if (client.available()) {
            client.poll();
        }
    }
}

GeSHi © Codebox Plus Extension

And the task for blinking an LED looks like this:

Code: [Select all] [Expand/Collapse]

void blinkLED(void *parameter) {
    int time = 1000;
    pinMode(led_pin, OUTPUT);
    Serial.print("Blinking LED task running on core ");
    Serial.println(xPortGetCoreID());
    for (;;) {
        digitalWrite(led_pin, HIGH);
        vTaskDelay(time / portTICK_PERIOD_MS);
        digitalWrite(led_pin, LOW);
        vTaskDelay(time / portTICK_PERIOD_MS);
    }
}

GeSHi © Codebox Plus Extension

Something I don't get is that the first declared task in the main code is the one that runs (no matter the priority or the core), which means that if I declare the video transmission task first, that only task runs. But if I declare the blinking LED first, that only task runs.

I've already tried by changing their running core, stack size and even running them both on the same core and deleting the setup() and loop() functions.

Any idea why this happens? Thanks in advance

Posted: **Sat Feb 03, 2024 8:30 am**

You request a total of 400K of stack space for the tasks. Likely you don't have that much internal memory available.

Posted: **Sat Feb 03, 2024 11:30 am**

Note that xTaskCreate tells you whether or not it was able to actually create the task via its return value:

If the task was created successfully then pdPASS is returned. Otherwise errCOULD_NOT_ALLOCATE_REQUIRED_MEMORY is returned.

https://www.freertos.org/a00125.html

Posted: **Sat Feb 03, 2024 4:10 pm**

ESP_Sprite wrote: ↑
Sat Feb 03, 2024 8:30 am
You request a total of 400K of stack space for the tasks. Likely you don't have that much internal memory available.

It seems to be true, I allocated 100000 bytes each and it worked.

Posted: **Sat Feb 03, 2024 4:30 pm**

MicroController wrote: ↑
Sat Feb 03, 2024 11:30 am
Note that xTaskCreate tells you whether or not it was able to actually create the task via its return value:
If the task was created successfully then pdPASS is returned. Otherwise errCOULD_NOT_ALLOCATE_REQUIRED_MEMORY is returned.
https://www.freertos.org/a00125.html

Thank you! I changed the setup() function like this:

Code: [Select all] [Expand/Collapse]

    if (xTaskCreatePinnedToCore(videoProjection, "Video projection", 200000, NULL, 2, &video, 1) != pdPASS) {
        Serial.println("video not allocated :(");
    }
 
    if (xTaskCreatePinnedToCore(blinkLED, "blink LED", 200000, NULL, 1, &led, 0) != pdPASS) {
        Serial.println("LED blinking not allocated :(");
    }

And I got the following output:

LED blinking not allocated
[ 1338][esp32-hal-i2c.c:75] i2cInit(): Initialising I2C Master: sda=19 scl=20 freq=100000
[ 1340][esp32-hal-i2c.c:75] i2cInit(): Initialising I2C Master: sda=19 scl=20 freq=100000
Video task running on core 1

So I allocated 100k for each task and I got both running

Posted: **Sun Feb 04, 2024 3:21 am**

100kb of stack per task is way too much. 4-16kb per task is sufficient for almost all tasks.

ESP32 Forum

One of the tasks attached to a core doesn't run

One of the tasks attached to a core doesn't run

Re: One of the tasks attached to a core doesn't run

Re: One of the tasks attached to a core doesn't run

Re: One of the tasks attached to a core doesn't run

Re: One of the tasks attached to a core doesn't run

Re: One of the tasks attached to a core doesn't run