ESP32 Forum

Posted: **Sun May 24, 2020 7:09 pm**

Hey,
on the ESP8266 (Arduino Framework) it was pretty easy to access the UART registers. All relevant registers were exposed in the esp8266_peri.h I used UART1 to generate a precise timed pulse using:

Code: [Select all] [Expand/Collapse]

    // Initial Setup
    pinMode(2, SPECIAL); // Set GPIO2 as UART1 TX
    U1S |= 0x01 << USTXC; // Set UART1 TX FIFO length
    U1D = 10*duration; // Set pulse duration using divider
    
    // To generate one pulse whenever I want without blocking CPU
    U1F = 0x80; // Pulse

GeSHi © Codebox Plus Extension

On the ESP32 (Arduino Framework) it is pretty hard to figure out how to access the relevant registers... At least for me. The HardwareSerial.cpp uses a lot of internal APIs.
So far I found out how to set the pin matrix to route the UART1 TX to GPIO2 and set the clock divider:

Code: [Select all] [Expand/Collapse]

    // Initial Setup
    Serial1.begin(9600); // Needed for Serial1.write to work (want to get rid of)
    pinMode(2, OUTPUT);
    pinMatrixOutAttach(2, U1TXD_OUT_IDX, false, false);
    WRITE_PERI_REG(UART_CLKDIV_REG(1), 10*duration); // requires <soc/uart_reg.h>
 
    // To generate one pulse
    Serial1.write(0x80);

GeSHi © Codebox Plus Extension

But I was not able to find the FIFO to write to... Using Serial1.write() blocks the CPU.
Can someone help me out here? Thx!

Posted: **Mon May 25, 2020 8:09 pm**

Okay, guess I somehow missed it the last weekend, but now I found it

Code: [Select all] [Expand/Collapse]

    // Initial Setup
    DPORT_SET_PERI_REG_MASK(DPORT_PERIP_CLK_EN_REG, DPORT_UART1_CLK_EN); // Enable Clock for UART1
    DPORT_CLEAR_PERI_REG_MASK(DPORT_PERIP_RST_EN_REG, DPORT_UART1_RST); // Enable UART1
    pinMode(2, OUTPUT);
    pinMatrixOutAttach(2, UART_TXD_IDX(1), false, false); // UART_TXD_IDX(u) / U1TXD_OUT_IDX
    WRITE_PERI_REG(UART_CLKDIV_REG(1), 10*duration); // requires <soc/uart_reg.h>
 
    // To generate one pulse
    WRITE_PERI_REG(UART_FIFO_REG(1), 0x80);

GeSHi © Codebox Plus Extension

For those who are curious how this generates a pulse of a fixed duration - in this case a LOW pulse:
The UART is usually HIGH on idle.
When it sends a character/byte, it sends one start-bit first, which is LOW, then the usually 8 bits data, and then a STOP bit (HIGH).
By sending 0x80, it generates 8 consecutive LOW bits (1 Start, 7 data).
The length of each bit is derived from the base clock of 80MHz and the clock divider. A division by 10 results in an 8 MHz clock or 1µs duration for sending the 8 LOW bits.

Posted: **Tue May 26, 2020 9:42 pm**

Okay, I now ran into another issue ... The code works fine if there is a long pause between pulses.
For a 5µs pulse, issues arise when I try to send a pulse within the next ~160µs.
When I try to create a pulse every 100µs, they are batched up and sent every ~160µs.

Here is the code:

Code: [Select all] [Expand/Collapse]

void setup() {
  pinMode(4, OUTPUT);
  DPORT_SET_PERI_REG_MASK(DPORT_PERIP_CLK_EN_REG, DPORT_UART1_CLK_EN); // Enable Clock
  DPORT_CLEAR_PERI_REG_MASK(DPORT_PERIP_RST_EN_REG, DPORT_UART1_RST); // Enable UART1
  pinMode(2, OUTPUT);
  pinMatrixOutAttach(2, UART_TXD_IDX(1), false, false); // UART_TXD_IDX(u) / U1TXD_OUT_IDX
  WRITE_PERI_REG(UART_CLKDIV_REG(1), 10*5); // 5µs pulse
}
 
void loop() {
  digitalWrite(4,LOW);
  WRITE_PERI_REG(UART_FIFO_REG(1), 0x80); // pulse
  digitalWrite(4,HIGH);
  while ( (READ_PERI_REG(UART_STATUS_REG(1)) & UART_TXD) < 1 )
  {
    digitalWrite(4,LOW); // Toggle while TX is LOW
    digitalWrite(4,HIGH);
  }
  
  //delayMicroseconds(180); // Works fine with 5µs
  delayMicroseconds(100); // Out of sync with 5µs pulse, fine with 2µs pulses
}

GeSHi © Codebox Plus Extension

180µs pause (what I want):

: 2020-05-26 23_10_33-Window.png (12.88 KiB) Viewed 3757 times

100µs pause (out of sync / batched):

: 2020-05-26 23_13_01-Window.png (13.96 KiB) Viewed 3757 times

When I reduce the pulse length to 2µs, both work... So I guess the gap is always ~32 pulses/characters ...

How do I reduce this?

Posted: **Wed May 27, 2020 8:48 am**

Not sure, but perhaps UART_TX_IDLE_NUM has something to do with it? You may want to try setting that to 0.

While you're reading the TRM anyway, can I advise you to read into the RMT peripheral? It's actually designed to generate arbitrary waveforms and is way better at it than the UART will ever be.

Posted: **Wed May 27, 2020 2:13 pm**

Thx, you're right. This is explained in the datasheet on "13.3.5 UART Data Frame" ... UART_TX_IDLE_NUM explains the gap.

Code: [Select all] [Expand/Collapse]

        CLEAR_PERI_REG_MASK( UART_IDLE_CONF_REG(1), UART_TX_BRK_NUM_M );
        CLEAR_PERI_REG_MASK( UART_IDLE_CONF_REG(1), UART_TX_IDLE_NUM_M );

solved the issue!

I went with the UART1 because I used it also on the ESP8266 and it works just fine for me

My requirements are:
- Trigger a pulse of a given length (~1-500µs) without blocking the CPU and as fast as possible (usually from within an ISR)
- Ability to check if the pulse is done whenever I want
- let me invert the pulse
- nice to have: possibility to specify the IO

The ESP8266 has a fixed IO for the UART1 TX and also has an issue with the Status-Register actually not reflecting the TX level as it should, but I fixed that with loopback mode.
So, triggering the pulse and reading the state are actually both only one write/read instruction. Setting the length is also just one write.

But thx for pointing me to the RMT, I'll have a look at it.

ESP32 Forum

Direct access to UART1 TX FIFO

Direct access to UART1 TX FIFO

Re: Direct access to UART1 TX FIFO

Re: Direct access to UART1 TX FIFO

Re: Direct access to UART1 TX FIFO

Re: Direct access to UART1 TX FIFO